Fao : Gg

[Smee]

Bud
I had to reformat today, so I did :E and I put mirc 6.01 on and that away script by moose, however for some reason it won't work like it did last night, I type my away reason etc and it doesn't show up on any of the channels :{ last night it did, I set it up the same away and everything. so would you be able to script one for me? doesn't have to be fancy, just something like

*Jynxeh is away -: Reason :- at time
*Jynxeh is back from -: reason :- gone time

PLEASEEEE :)

Jynxeh.

[GameGuru]

no, cos u called me Gg :p (It's GG damnit!)

Oh all right then...


alias a {
ame is away - $+ $chr(91) $$1 $chr(93) $+ - at - $+ $chr(91) $time $chr(93) $+ -
away $$1
%away = $$1
}
alias b {
ame is back from - $+ $chr(91) %away $chr(93) $+ - at - $+ $chr(91) $time $chr(93) $+ -
away
unset %away
}
That goes in the remote section (Alt + R)
Might refine it later, but that should work for the time being

[Smee]

That doesn't show up on the channels :{ I'm using 6.01 would that be something to do with it?

[Uranium]

Pfft has no auto away function :P

[Uranium]

I just tried it and I have 6.01 and works fine. You sure you using it right? eg you typing /a gone out ?

[Smee]

yeah, it shows up in the status box :{ "You have been marked as being away" thats only in the status box, not in any of the channles so people know.

[GameGuru]

You may want to change the alias names if they conflict with already existing aliases.

Sample Popup file:

Away Script
.Set Away
..BRB: a BRB
..Food: a Food
..Sleep: a Sleep
..Custom: a $$?"Enter an away message"
.Set Back: b


add it to the channel section of the popups file (if you don't know how check my second guide to mIRC scripting, which is in my sig)

[Strembles]

How about this, I refined GameGuru's away script a bit and made it so that you cannot set away if you're already away and vise versa :)
I also changed it so that you are able to use an away reason with more than one word :P


alias a {
if ($away) {
echo -a You're Already Away
halt
}
else {
ame is away - $+ $chr(91) $$1- $chr(93) $+ - at - $+ $chr(91) $time $chr(93) $+ -
away $$1-
%away = $$1-
}
}


alias b {
if ($away) {
ame is back from - $+ $chr(91) %away $chr(93) $+ - at - $+ $chr(91) $time $chr(93) $+ -
away
unset %away
}
else {
echo -a You're Not Away.
}
}

menu channel {
Away Script
.$iif($away,$style(2)) Set Away
..BRB: a BRB
..Food: a Food
..Sleep: a Sleep
..Custom: a $$?"Enter an away message:"
.$iif(!$away,$style(2)) Set Back: b
}


Just copy that into your remotes, then type "/a reason" to set away or "/b" to set back. You can also right click in the channel to set away or back. :E

[Smee]

whats the code bit so on set back it shows how long I been away, i.e back after 8hr 34 secs 15mins I thought it was $duration but I don't know for sure, even if I did where do I put it?

[GameGuru]

As soon as I recover from last nights activities I'll add that bit.
Good work on refining the script Stremblax, I forgot I only allowed one word reasons :E

[Strembles]

Hey NP, glad to help :), I shall have a go at the code that says how long you've been away for later (I can't really be arsed to do it right now :))

[Strembles]

Right, this should do the job:


alias a {
if ($away) {
echo -a You're Already Away
halt
}
else {
set %left $ctime
ame is away - $+ $chr(91) $$1- $chr(93) $+ - at - $+ $chr(91) $asctime(hh:nn) $chr(93) $+ -
away $$1-
%away = $$1-
}
}


alias b {
if ($away) {
ame is back from - $+ $chr(91) %away $chr(93) $+ - gone for - $+ $chr(91) $duration($calc($ctime - %left)) $chr(93) $+ -
away
unset %away %left
}
else {
echo -a You're Not Away.
}
}

menu channel {
Away Script
.$iif($away,$style(2)) Set Away
..BRB: a BRB
..Food: a Food
..Sleep: a Sleep
..Custom: a $$?"Enter an away message:"
.$iif(!$away,$style(2)) Set Back: b
}


Note: Just realised that this probably wont set you away on multiple servers, I'm not really sure how to do that at the moment, but I shall look into it :)
(or maybe GameGuru can shed some light on the matter:E)

[GameGuru]

You're indeed right, it only works if you connect to a single server, or use multiple mIRC's to connect to multiple servers and connect individually. I've not really considered a way around that problem yet...

Damn you new mIRC!111

[Strembles]

Apparently you need to use $cid or something(can't quite remember off the top of my head :))

/me goes to read the mirc help file :)

[Strembles]

Right then, read up a little bit and it seems that I need to use scid -a :)
Heres a quick change then:


alias a {
if ($away) {
echo -a You're Already Away
halt
}
else {
set %left $ctime
scid -a ame is away - $+ $chr(91) $$1- $chr(93) $+ - at - $+ $chr(91) $asctime(hh:nn) $chr(93) $+ -
scid -a away $$1-
%away = $$1-
}
}


alias b {
if ($away) {
scid -a ame is back from - $+ $chr(91) %away $chr(93) $+ - gone for - $+ $chr(91) $duration($calc($ctime - %left)) $chr(93) $+ -
scid -a away
unset %away %left
}
else {
echo -a You're Not Away.
}
}

menu channel {
Away Script
.$iif($away,$style(2)) Set Away
..BRB: a BRB
..Food: a Food
..Sleep: a Sleep
..Custom: a $$?"Enter an away message:"
.$iif(!$away,$style(2)) Set Back: b
}

Not actually tested this yet, so I've no idea if it will work :/

[Smee]

I've been using the away script since last night, it's very good :) normal mirc and a custom away script is far better, thank you GG and Stremblax

[Smee]

Just wondering, I need a little script so if anyone was to say my name it would say "Jynxeh is away" or even "Jynxeh is away, doing *reason*"

[GameGuru]

on *:text:$(* $+ $me $+ *):#: {
if ( %away != null ) {
notice $nick I am currently away, %away $+ , sent in response to " $+ $me $+ "
}
}

I think that'll do what you want...

[Smee]

and that goes into the remote section?

[GameGuru]

yes it does. Stick it at the bottom

[Strembles]

we're doing pretty well I must say :D

soon this away script will have dialogs, logging, a hat designer and a little robot that comes out and cooks your food :)

(hopefully anyway:E)